D.P.

SK 7/2026

U poslednjih nekoliko izdanja, raspisali smo se o LoRa komunikaciji. Bilo je dosta reči i kako sve to funkcioniše, tako da sada taj deo preskačemo. Pišemo o jednom modulu iz firme Ai-Thinker koji smo dobili dosta davno, kad i neke razvojne ploče koje su našle mesta na ovim stranicama. U međuvremenu smo za neke naše opširne testove sa LoRa modulima isprobali i ovaj iz naslova.

RA-01h je modul koji ispod metalnog poklopca krije dobro poznati SX1276, sa kojim smo se više puta susretali. Prvi put je to bilo sa Heltecovom pločom (SK 3/2019, i.sk.rs/15732). Bavili smo se i klasičnim SX1276 bezimenim modulima i RadioLib bibliotekom i nikada nismo imali problema. Sada ćemo se malo pozabaviti povezivanjem RA-01h LoRa modula sa ATmega328p mikrokontrolerom i specifičnostima na koje smo naišli.

LoRa modul napaja se sa 3,3 volta, pa je poželjno da se upotrebi sa razvojna ploča koja koristi isti napon ili da se upotrebe pomerači naponske logike. Da biste pratili naš primer, uzmite Pro Mini na osam megaherca i 3,3 volta, sa RA-01h. Radi naših testova, napravili smo štampanu pločicu i sve komponente spustili na PCB. Interno povezivanje obavlja se na sledeći način:

SCK - D13

MISO - D12

MOSI - D11

CS - D10

RESET - D9

DIO0 - D2

Ovo je klasično SPI povezivanje, jer, kao što znamo, SX1276 koristi SPI magistralu za komunikaciju sa mikrokontrolerom. RESET liniju možete da povežete sa bilo kojim digitalnim izvodom, dok DIO0 kao prekidački izvod mora ići na neki INT, a na ATmega328p to je D2 (INT0).

Već prvi problem na koji smo naišli jeste da RadioLib biblioteka i primeri zauzimaju mnogo prostora koji naš MCU naprosto nema. Rešenje je prelazak na LoRa biblioteku (Sandeep Mistry - GitHub) koja ne zauzima mnogo prostora i bez ikakvih problema možemo da razvijamo projekat sa hardverom koji koristimo ovde. Upotrebili smo RAK3172 (SK 6/2026, i.sk.rs/35610) u ulozi predajnika, sa primerom ispod. RAK3172 će naprosto slati jedan broj koji će se svakom porukom uvećavati.

##include <Arduino.h>

#define LED_PIN PA8

struct __attribute__((packed)) Payload {

  uint8_t chipID[8];

  uint32_t counter;

};

Payload myData;

uint32_t txCounter = 0;

void setup() {

  Serial.begin(115200);

  delay(2000);

  pinMode(LED_PIN, OUTPUT);

  if (api.lora.nwm.get() != 0) {

    api.lora.nwm.set();

    api.system.reboot();

  }

  api.lora.pfreq.set(868000000);

  api.lora.psf.set(7);

  api.lora.pbw.set(125);

  api.lora.pcr.set(1);

  api.lora.ppl.set(8);

  api.lora.ptp.set(14);

  api.lorawan.deui.get(myData.chipID, 8);

}

void loop() {

  api.lora.precv(0);

  myData.counter = txCounter++;

  if (api.lora.psend(sizeof(Payload), (uint8_t *)&myData)) {

    Serial.print("POSLAT ID + CNT: ");

    Serial.println(myData.counter);

    digitalWrite(LED_PIN, HIGH);

    delay(50);

    digitalWrite(LED_PIN, LOW);

  }

  delay(2000);

}

Na ATmega328p i RA-01h upotrebili smo primer ispod. Čitamo taj poslat broj, a usput pratimo redosled primljenih paketa, ali i RSSI vrednost.

#include <SPI.h>

#include <LoRa.h>

#define LORA_CS   10

#define LORA_RST   9

#define LORA_DIO0 2

void setup() {

  Serial.begin(115200);

  LoRa.setPins(LORA_CS, LORA_RST, LORA_DIO0);

  if (!LoRa.begin(868E6)) {

    Serial.println("LoRa FAIL");

    while (1);

  }

  LoRa.setSpreadingFactor(7);

  LoRa.setSignalBandwidth(125E3);

  LoRa.setCodingRate4(8);

  LoRa.setSyncWord(0x12);

  LoRa.receive();

  Serial.println("READY");

}

void loop() {

  int packetSize = LoRa.parsePacket();

  if (!packetSize) return;

  uint8_t buf[32];

  int i = 0;

  while (LoRa.available() && i < sizeof(buf)) {

    buf[i++] = LoRa.read();

  }

  if (i < 12) {

    Serial.println("SHORT PKT");

    LoRa.receive();

    return;

  }

  uint32_t cnt;

  memcpy(&cnt, &buf[8], 4);

  Serial.print("CNT: ");

  Serial.print(cnt);

  Serial.print(" RSSI: ");

  Serial.println(LoRa.packetRssi());

  LoRa.receive();

}

Možete da uporedite ova dva primera i vidite da, bez obzira na to što smo koristili različit hardver i različite biblioteke, ova dva uređaja međusobno savršeno komuniciraju. Osnovno je da se usaglase parametri u funkciji setup(). O ovim parametrima smo već pisali u pomenutom tekstu, ali i u zasebnom tekstu koji možete da pročitate u SK 4/2026 (i.sk.rs/35459).

U narednom periodu, potrudićemo se da napravimo projekat sa ESP32 i SX1276 bezimenim modulom, ali i RadioLib bibliotekom koja svakako daje više mogućnosti, a i pokriva širu paletu LoRa čipova.